HSPICEの使い方

あなたは平成22年10月20日以来

人目のお客様です

もくじ


回路に流れている電流のはかり方

回路に流れている電流を測定したい場合は、電圧ゼロの電圧源を使います。以下のネットリストを見てみましょう。

test inv (br-DC)

(↓NMOSとPMOSのゲート幅の比率が異なる3つのインバータです)
**** br=0.1 ****
mp1 out1 in t2 t2 pm l=4u w=160u ad=1600p as=1600p pd=340u ps=340u
mn1 out1 in 0 0 nm l=4u w=8u ad=80p as=80p pd=36u ps=36u
**** br=1 ****  
mp2 out2 in t3 t3 pm l=4u w=16u ad=160p as=160p pd=52u ps=52u 
mn2 out2 in 0 0 nm l=4u w=8u ad=80p as=80p pd=36u ps=36u      
**** br=10 ****                                               
mp3 out3 in t4 t4 pm l=4u w=8u ad=80p as=80p pd=100u ps=100u
mn3 out3 in 0 0 nm l=4u w=40u ad=400p as=400p pd=100u ps=100u

**** MOS FET model ****
.model nm nmos (level=2 vto=1.0 tox=0.035u nsub=1e15 uo=500
+ ucrit=4.5e4 uexp=0.11 tpg=1 ld=0.2u xj=0.29u js=6m pb=0.94
+ cj=3.85e-4 cjsw=1.6n cgdo=0.45n cgso=0.45n cgbo=0.042n
+ rd=1 rs=1)
.model pm pmos (level=2 vto=-1.0 tox=0.035u nsub=1e16 uo=250
+ ucrit=2.0e4 uexp=0.08 tpg=-1 ld=0.3u xj=0.43u js=6m pb=0.88
+ cj=1.23e-4 cjsw=2.36n cgdo=0.25n cgso=0.25n cgbo=0.02n
+ rd=1 rs=1)

**** power supply ****
vdd t1 0 dc 5
vin in 0 dc 5

vim1 t1 t2 dc 0   この3つの電圧源が電流計の役目をしています。
vim2 t1 t3 dc 0   見ての通り電圧ゼロの電圧源を使っています。
vim3 t1 t4 dc 0   ちなみに接続の向きが反対のときは出力される数値が負の値になります。

**** control ****
.dc vin 0 5 0.1
.print v(out1) v(out2) v(out3)
(↑各インバータの出力電圧を見ています。)
.print i(vim1) i(vim2) i(vim3)  
(↑各インバータに流れ込む電流を見ています。)
.end


ネットリストの回路図

このネットリスト特性を変えた3つのインバータの入出力特性と回路への突入電流の大きさを調べるためのものです。電流計として電圧が零の電圧源を使っています。 電流の向きについては、電流の流れがプラス側からマイナス側に流れるときに結果ファイルでの値が正の値になります。従って、全体の消費電流を調べようとして電源Vddに流れる電流を出力させると結果ファイルでは負の値で出力されます。

直流解析や過渡解析では電流の値は瞬時値で出力されます。平均値を調べるには、結果ファイル中のデータを表計算ソフトにでも入れて計算すれば出ると思います。直接やる方法もあるそうです。






累計 本日 昨日